home *** CD-ROM | disk | FTP | other *** search
/ Scene Storm / Scene Storm - Volume 1.iso / coding / asm / demos / retinarave / include / pt-playa.s < prev    next >
Text File  |  1980-01-03  |  23KB  |  1,182 lines
  1. ;********************************************
  2. ;* ----- Protracker V1.1B Playroutine ----- *
  3. ;* Lars "Zap" Hamre/Amiga Freelancers 1991  *
  4. ;* Bekkeliveien 10, N-2010 STRØMMEN, Norway *
  5. ;********************************************
  6.  
  7. ; VBlank Version 2:
  8. ; Call mt_init to initialize the routine, then call mt_music on
  9. ; each vertical blank (50 Hz). To end the song and turn off all
  10. ; voices, call mt_end.
  11.  
  12. ; This playroutine is not very fast, optimized or well commented,
  13. ; but all the new commands in PT1.1A should work.
  14. ; If it's not good enough, you'll have to change it yourself.
  15. ; We'll try to write a faster routine soon...
  16.  
  17. ; Changes from V1.0C playroutine:
  18. ; - Vibrato depth changed to be compatible with Noisetracker 2.0.
  19. ;   You'll have to double all vib. depths on old PT modules.
  20. ; - Funk Repeat changed to Invert Loop.
  21. ; - Period set back earlier when stopping an effect.
  22.  
  23. DMAWait = 300 ; Set this as low as possible without losing low notes.
  24.  
  25. n_note        EQU    0  ; W
  26. n_cmd        EQU    2  ; W
  27. n_cmdlo        EQU    3  ; B
  28. n_start        EQU    4  ; L
  29. n_length    EQU    8  ; W
  30. n_loopstart    EQU    10 ; L
  31. n_replen    EQU    14 ; W
  32. n_period    EQU    16 ; W
  33. n_finetune    EQU    18 ; B
  34. n_volume    EQU    19 ; B
  35. n_dmabit    EQU    20 ; W
  36. n_toneportdirec    EQU    22 ; B
  37. n_toneportspeed    EQU    23 ; B
  38. n_wantedperiod    EQU    24 ; W
  39. n_vibratocmd    EQU    26 ; B
  40. n_vibratopos    EQU    27 ; B
  41. n_tremolocmd    EQU    28 ; B
  42. n_tremolopos    EQU    29 ; B
  43. n_wavecontrol    EQU    30 ; B
  44. n_glissfunk    EQU    31 ; B
  45. n_sampleoffset    EQU    32 ; B
  46. n_pattpos    EQU    33 ; B
  47. n_loopcount    EQU    34 ; B
  48. n_funkoffset    EQU    35 ; B
  49. n_wavestart    EQU    36 ; L
  50. n_reallength    EQU    40 ; W
  51.  
  52. mt_init    Lea    Mt_data,A0
  53.     MOVE.L    A0,mt_SongDataPtr
  54.     MOVE.L    A0,A1
  55.     LEA    952(A1),A1
  56.     MOVEQ    #127,D0
  57.     MOVEQ    #0,D1
  58. mtloop    MOVE.L    D1,D2
  59.     SUBQ.W    #1,D0
  60. mtloop2    MOVE.B    (A1)+,D1
  61.     CMP.B    D2,D1
  62.     BGT.S    mtloop
  63.     DBRA    D0,mtloop2
  64.     ADDQ.B    #1,D2
  65.             
  66.     LEA    mt_SampleStarts(PC),A1
  67.     ASL.L    #8,D2
  68.     ASL.L    #2,D2
  69.     ADD.L    #1084,D2
  70.     ADD.L    A0,D2
  71.     MOVE.L    D2,A2
  72.     MOVEQ    #30,D0
  73. mtloop3    CLR.L    (A2)
  74.     MOVE.L    A2,(A1)+
  75.     MOVEQ    #0,D1
  76.     MOVE.W    42(A0),D1
  77.     ASL.L    #1,D1
  78.     ADD.L    D1,A2
  79.     ADD.L    #30,A0
  80.     DBRA    D0,mtloop3
  81.  
  82.     OR.B    #2,$BFE001
  83.     MOVE.B    #6,mt_speed
  84.     CLR.B    mt_counter
  85.     CLR.B    mt_SongPos
  86.     CLR.W    mt_PatternPos
  87. mt_end    CLR.W    $DFF0A8
  88.     CLR.W    $DFF0B8
  89.     CLR.W    $DFF0C8
  90.     CLR.W    $DFF0D8
  91.     MOVE.W    #$F,$DFF096
  92.     RTS
  93.  
  94. mt_music
  95.     MOVEM.L    D0-D4/A0-A6,-(SP)
  96.     sub.w #$022,Equalizer1
  97.     bpl Eq1Ok
  98.     move.w #0,Equalizer1
  99. Eq1Ok:
  100.     sub.w #$020,Equalizer2
  101.     bpl Eq2Ok
  102.     move.w #0,Equalizer2
  103. Eq2Ok:
  104.     sub.w #$222,Equalizer3
  105.     bpl Eq3Ok
  106.     move.w #0,Equalizer3
  107. Eq3Ok:
  108.     sub.w #$202,Equalizer4
  109.     bpl Eq4Ok
  110.     move.w #0,Equalizer4
  111. Eq4Ok:
  112.  
  113.  
  114.  
  115.     ADDQ.B    #1,mt_counter
  116.     MOVE.B    mt_counter(PC),D0
  117.     CMP.B    mt_speed(PC),D0
  118.     BLO.S    mt_NoNewNote
  119.     CLR.B    mt_counter
  120.     TST.B    mt_PattDelTime2
  121.     BEQ.S    mt_GetNewNote
  122.     BSR.S    mt_NoNewAllChannels
  123.     BRA    mt_dskip
  124.  
  125. mt_NoNewNote
  126.     BSR.S    mt_NoNewAllChannels
  127.     BRA    mt_NoNewPosYet
  128.  
  129. mt_NoNewAllChannels
  130.     LEA    $DFF0A0,A5
  131.     LEA    mt_chan1temp(PC),A6
  132.     BSR    mt_CheckEfx
  133.     LEA    $DFF0B0,A5
  134.     LEA    mt_chan2temp(PC),A6
  135.     BSR    mt_CheckEfx
  136.     LEA    $DFF0C0,A5
  137.     LEA    mt_chan3temp(PC),A6
  138.     BSR    mt_CheckEfx
  139.     LEA    $DFF0D0,A5
  140.     LEA    mt_chan4temp(PC),A6
  141.     BRA    mt_CheckEfx
  142.  
  143. mt_GetNewNote
  144.     MOVE.L    mt_SongDataPtr(PC),A0
  145.     LEA    12(A0),A3
  146.     LEA    952(A0),A2    ;pattpo
  147.     LEA    1084(A0),A0    ;patterndata
  148.     MOVEQ    #0,D0
  149.     MOVEQ    #0,D1
  150.     MOVE.B    mt_SongPos(PC),D0
  151.     MOVE.B    (A2,D0.W),D1
  152. ;this is is a note steve
  153.     ASL.L    #8,D1
  154.     ASL.L    #2,D1
  155.     ADD.W    mt_PatternPos(PC),D1
  156.     CLR.W    mt_DMACONtemp
  157.  
  158.     LEA    $DFF0A0,A5
  159.     LEA    mt_chan1temp(PC),A6
  160.     BSR.S    mt_PlayVoice
  161.     LEA    $DFF0B0,A5
  162.     LEA    mt_chan2temp(PC),A6
  163.     BSR.S    mt_PlayVoice
  164.     LEA    $DFF0C0,A5
  165.     LEA    mt_chan3temp(PC),A6
  166.     BSR.S    mt_PlayVoice
  167.     LEA    $DFF0D0,A5
  168.     LEA    mt_chan4temp(PC),A6
  169.     BSR.S    mt_PlayVoice
  170.     BRA    mt_SetDMA
  171.  
  172. mt_PlayVoice
  173.     TST.L    (A6)
  174.     BNE.S    mt_plvskip
  175.     BSR    mt_PerNop
  176. mt_plvskip
  177.     MOVE.L    (A0,D1.L),(A6)
  178.     ADDQ.L    #4,D1
  179.     MOVEQ    #0,D2
  180.     MOVE.B    n_cmd(A6),D2
  181.     AND.B    #$F0,D2
  182.     LSR.B    #4,D2
  183.     MOVE.B    (A6),D0
  184.     AND.B    #$F0,D0
  185.     OR.B    D0,D2
  186.     TST.B    D2
  187.     BEQ    mt_SetRegs
  188.     MOVEQ    #0,D3
  189.     LEA    mt_SampleStarts(PC),A1
  190.     MOVE    D2,D4
  191.     SUBQ.L    #1,D2
  192.     ASL.L    #2,D2
  193.  
  194.  
  195. ; sub #22,d4 here should be sample number I think
  196. ;
  197. ; then the following compares will tell you the channel
  198. ;
  199.  
  200.     cmp.l #$dff0a0,a5
  201.     bne NoEqu1
  202.     move.w #$0ff,Equalizer1
  203.     move.w d4,chan1
  204. NoEqu1:
  205.     cmp.l #$dff0b0,a5
  206.     bne NoEqu2
  207.     move.w #$f0,Equalizer2
  208.     move.w d4,chan2
  209. NoEqu2:
  210.     cmp.l #$dff0c0,a5
  211.     bne NoEqu3
  212.     move.w #$fFF,Equalizer3
  213.     move.w d4,chan3
  214. NoEqu3:
  215.     cmp.l #$dff0d0,a5
  216.     bne NoEqu4
  217.     move.w #$f0f,Equalizer4
  218.     move.w d4,chan4
  219. NoEqu4:
  220.  
  221.  
  222.     MULU    #30,D4
  223.     MOVE.L    (A1,D2.L),n_start(A6)
  224.     MOVE.W    (A3,D4.L),n_length(A6)
  225.     MOVE.W    (A3,D4.L),n_reallength(A6)
  226.     MOVE.B    2(A3,D4.L),n_finetune(A6)
  227.     MOVE.B    3(A3,D4.L),n_volume(A6)
  228.     MOVE.W    4(A3,D4.L),D3 ; Get repeat
  229.     TST.W    D3
  230.     BEQ.S    mt_NoLoop
  231.     MOVE.L    n_start(A6),D2    ; Get start
  232.     ASL.W    #1,D3
  233.     ADD.L    D3,D2        ; Add repeat
  234.     MOVE.L    D2,n_loopstart(A6)
  235.     MOVE.L    D2,n_wavestart(A6)
  236.     MOVE.W    4(A3,D4.L),D0    ; Get repeat
  237.     ADD.W    6(A3,D4.L),D0    ; Add replen
  238.     MOVE.W    D0,n_length(A6)
  239.     MOVE.W    6(A3,D4.L),n_replen(A6)    ; Save replen
  240.     MOVEQ    #0,D0
  241.     MOVE.B    n_volume(A6),D0
  242.     MOVE.W    D0,8(A5)    ; Set volume
  243.     BRA.S    mt_SetRegs
  244.  
  245. mt_NoLoop
  246.     MOVE.L    n_start(A6),D2
  247.     ADD.L    D3,D2
  248.     MOVE.L    D2,n_loopstart(A6)
  249.     MOVE.L    D2,n_wavestart(A6)
  250.     MOVE.W    6(A3,D4.L),n_replen(A6)    ; Save replen
  251.     MOVEQ    #0,D0
  252.     MOVE.B    n_volume(A6),D0
  253.     MOVE.W    D0,8(A5)    ; Set volume
  254. mt_SetRegs
  255.     MOVE.W    (A6),D0
  256.     AND.W    #$0FFF,D0
  257.     BEQ    mt_CheckMoreEfx    ; If no note
  258.     MOVE.W    2(A6),D0
  259.     AND.W    #$0FF0,D0
  260.     CMP.W    #$0E50,D0
  261.     BEQ.S    mt_DoSetFineTune
  262.     MOVE.B    2(A6),D0
  263.     AND.B    #$0F,D0
  264.     CMP.B    #3,D0    ; TonePortamento
  265.     BEQ.S    mt_ChkTonePorta
  266.     CMP.B    #5,D0
  267.     BEQ.S    mt_ChkTonePorta
  268.     CMP.B    #9,D0    ; Sample Offset
  269.     BNE.S    mt_SetPeriod
  270.     BSR    mt_CheckMoreEfx
  271.     BRA.S    mt_SetPeriod
  272.  
  273. mt_DoSetFineTune
  274.     BSR    mt_SetFineTune
  275.     BRA.S    mt_SetPeriod
  276.  
  277. mt_ChkTonePorta
  278.     BSR    mt_SetTonePorta
  279.     BRA    mt_CheckMoreEfx
  280.  
  281. mt_SetPeriod
  282.     MOVEM.L    D0-D1/A0-A1,-(SP)
  283.     MOVE.W    (A6),D1
  284.     AND.W    #$0FFF,D1
  285.     LEA    mt_PeriodTable(PC),A1
  286.     MOVEQ    #0,D0
  287.     MOVEQ    #36,D7
  288. mt_ftuloop
  289.     CMP.W    (A1,D0.W),D1
  290.     BHS.S    mt_ftufound
  291.     ADDQ.L    #2,D0
  292.     DBRA    D7,mt_ftuloop
  293. mt_ftufound
  294.     MOVEQ    #0,D1
  295.     MOVE.B    n_finetune(A6),D1
  296.     MULU    #36*2,D1
  297.     ADD.L    D1,A1
  298.     MOVE.W    (A1,D0.W),n_period(A6)
  299.     MOVEM.L    (SP)+,D0-D1/A0-A1
  300.  
  301.     MOVE.W    2(A6),D0
  302.     AND.W    #$0FF0,D0
  303.     CMP.W    #$0ED0,D0 ; Notedelay
  304.     BEQ    mt_CheckMoreEfx
  305.  
  306.     MOVE.W    n_dmabit(A6),$DFF096
  307.     BTST    #2,n_wavecontrol(A6)
  308.     BNE.S    mt_vibnoc
  309.     CLR.B    n_vibratopos(A6)
  310. mt_vibnoc
  311.     BTST    #6,n_wavecontrol(A6)
  312.     BNE.S    mt_trenoc
  313.     CLR.B    n_tremolopos(A6)
  314. mt_trenoc
  315.     MOVE.L    n_start(A6),(A5)    ; Set start
  316.     MOVE.W    n_length(A6),4(A5)    ; Set length
  317.     MOVE.W    n_period(A6),D0
  318.     MOVE.W    D0,6(A5)        ; Set period
  319.     MOVE.W    n_dmabit(A6),D0
  320.     OR.W    D0,mt_DMACONtemp
  321.     BRA    mt_CheckMoreEfx
  322.  
  323. mt_SetDMA
  324.     MOVE.W    #300,D0
  325. mt_WaitDMA
  326.     DBRA    D0,mt_WaitDMA
  327.     MOVE.W    mt_DMACONtemp(PC),D0
  328.     OR.W    #$8000,D0
  329.     MOVE.W    D0,$DFF096
  330.     MOVE.W    #300,D0
  331. mt_WaitDMA2
  332.     DBRA    D0,mt_WaitDMA2
  333.  
  334.     LEA    $DFF000,A5
  335.     LEA    mt_chan4temp(PC),A6
  336.     MOVE.L    n_loopstart(A6),$D0(A5)
  337.     MOVE.W    n_replen(A6),$D4(A5)
  338.     LEA    mt_chan3temp(PC),A6
  339.     MOVE.L    n_loopstart(A6),$C0(A5)
  340.     MOVE.W    n_replen(A6),$C4(A5)
  341.     LEA    mt_chan2temp(PC),A6
  342.     MOVE.L    n_loopstart(A6),$B0(A5)
  343.     MOVE.W    n_replen(A6),$B4(A5)
  344.     LEA    mt_chan1temp(PC),A6
  345.     MOVE.L    n_loopstart(A6),$A0(A5)
  346.     MOVE.W    n_replen(A6),$A4(A5)
  347.  
  348. mt_dskip
  349.     ADD.W    #16,mt_PatternPos
  350.     MOVE.B    mt_PattDelTime,D0
  351.     BEQ.S    mt_dskc
  352.     MOVE.B    D0,mt_PattDelTime2
  353.     CLR.B    mt_PattDelTime
  354. mt_dskc    TST.B    mt_PattDelTime2
  355.     BEQ.S    mt_dska
  356.     SUBQ.B    #1,mt_PattDelTime2
  357.     BEQ.S    mt_dska
  358.     SUB.W    #16,mt_PatternPos
  359. mt_dska    TST.B    mt_PBreakFlag
  360.     BEQ.S    mt_nnpysk
  361.     SF    mt_PBreakFlag
  362.     MOVEQ    #0,D0
  363.     MOVE.B    mt_PBreakPos(PC),D0
  364.     CLR.B    mt_PBreakPos
  365.     LSL.W    #4,D0
  366.     MOVE.W    D0,mt_PatternPos
  367. mt_nnpysk
  368.     CMP.W    #1024,mt_PatternPos
  369.     BLO.S    mt_NoNewPosYet
  370. mt_NextPosition    
  371.     MOVEQ    #0,D0
  372.     MOVE.B    mt_PBreakPos(PC),D0
  373.     LSL.W    #4,D0
  374.     MOVE.W    D0,mt_PatternPos
  375.     CLR.B    mt_PBreakPos
  376.     CLR.B    mt_PosJumpFlag
  377.     ADDQ.B    #1,mt_SongPos
  378.     AND.B    #$7F,mt_SongPos
  379.     MOVE.B    mt_SongPos(PC),D1
  380.     MOVE.L    mt_SongDataPtr(PC),A0
  381.     CMP.B    950(A0),D1
  382.     BLO.S    mt_NoNewPosYet
  383.     CLR.B    mt_SongPos
  384. mt_NoNewPosYet    
  385.     TST.B    mt_PosJumpFlag
  386.     BNE.S    mt_NextPosition
  387.     MOVEM.L    (SP)+,D0-D4/A0-A6
  388.     RTS
  389.  
  390. mt_CheckEfx
  391.     BSR    mt_UpdateFunk
  392.     MOVE.W    n_cmd(A6),D0
  393.     AND.W    #$0FFF,D0
  394.     BEQ.S    mt_PerNop
  395.     MOVE.B    n_cmd(A6),D0
  396.     AND.B    #$0F,D0
  397.     BEQ.S    mt_Arpeggio
  398.     CMP.B    #1,D0
  399.     BEQ    mt_PortaUp
  400.     CMP.B    #2,D0
  401.     BEQ    mt_PortaDown
  402.     CMP.B    #3,D0
  403.     BEQ    mt_TonePortamento
  404.     CMP.B    #4,D0
  405.     BEQ    mt_Vibrato
  406.     CMP.B    #5,D0
  407.     BEQ    mt_TonePlusVolSlide
  408.     CMP.B    #6,D0
  409.     BEQ    mt_VibratoPlusVolSlide
  410.     CMP.B    #$E,D0
  411.     BEQ    mt_E_Commands
  412. SetBack    MOVE.W    n_period(A6),6(A5)
  413.     CMP.B    #7,D0
  414.     BEQ    mt_Tremolo
  415.     CMP.B    #$A,D0
  416.     BEQ    mt_VolumeSlide
  417. mt_Return2
  418.     RTS
  419.  
  420. mt_PerNop
  421.     MOVE.W    n_period(A6),6(A5)
  422.     RTS
  423.  
  424. mt_Arpeggio
  425.     MOVEQ    #0,D0
  426.     MOVE.B    mt_counter(PC),D0
  427.     DIVS    #3,D0
  428.     SWAP    D0
  429.     CMP.W    #0,D0
  430.     BEQ.S    mt_Arpeggio2
  431.     CMP.W    #2,D0
  432.     BEQ.S    mt_Arpeggio1
  433.     MOVEQ    #0,D0
  434.     MOVE.B    n_cmdlo(A6),D0
  435.     LSR.B    #4,D0
  436.     BRA.S    mt_Arpeggio3
  437.  
  438. mt_Arpeggio1
  439.     MOVEQ    #0,D0
  440.     MOVE.B    n_cmdlo(A6),D0
  441.     AND.B    #15,D0
  442.     BRA.S    mt_Arpeggio3
  443.  
  444. mt_Arpeggio2
  445.     MOVE.W    n_period(A6),D2
  446.     BRA.S    mt_Arpeggio4
  447.  
  448. mt_Arpeggio3
  449.     ASL.W    #1,D0
  450.     MOVEQ    #0,D1
  451.     MOVE.B    n_finetune(A6),D1
  452.     MULU    #36*2,D1
  453.     LEA    mt_PeriodTable(PC),A0
  454.     ADD.L    D1,A0
  455.     MOVEQ    #0,D1
  456.     MOVE.W    n_period(A6),D1
  457.     MOVEQ    #36,D7
  458. mt_arploop
  459.     MOVE.W    (A0,D0.W),D2
  460.     CMP.W    (A0),D1
  461.     BHS.S    mt_Arpeggio4
  462.     ADDQ.L    #2,A0
  463.     DBRA    D7,mt_arploop
  464.     RTS
  465.  
  466. mt_Arpeggio4
  467.     MOVE.W    D2,6(A5)
  468.     RTS
  469.  
  470. mt_FinePortaUp
  471.     TST.B    mt_counter
  472.     BNE.S    mt_Return2
  473.     MOVE.B    #$0F,mt_LowMask
  474. mt_PortaUp
  475.     MOVEQ    #0,D0
  476.     MOVE.B    n_cmdlo(A6),D0
  477.     AND.B    mt_LowMask(PC),D0
  478.     MOVE.B    #$FF,mt_LowMask
  479.     SUB.W    D0,n_period(A6)
  480.     MOVE.W    n_period(A6),D0
  481.     AND.W    #$0FFF,D0
  482.     CMP.W    #113,D0
  483.     BPL.S    mt_PortaUskip
  484.     AND.W    #$F000,n_period(A6)
  485.     OR.W    #113,n_period(A6)
  486. mt_PortaUskip
  487.     MOVE.W    n_period(A6),D0
  488.     AND.W    #$0FFF,D0
  489.     MOVE.W    D0,6(A5)
  490.     RTS    
  491.  
  492. mt_FinePortaDown
  493.     TST.B    mt_counter
  494.     BNE    mt_Return2
  495.     MOVE.B    #$0F,mt_LowMask
  496. mt_PortaDown
  497.     CLR.W    D0
  498.     MOVE.B    n_cmdlo(A6),D0
  499.     AND.B    mt_LowMask(PC),D0
  500.     MOVE.B    #$FF,mt_LowMask
  501.     ADD.W    D0,n_period(A6)
  502.     MOVE.W    n_period(A6),D0
  503.     AND.W    #$0FFF,D0
  504.     CMP.W    #856,D0
  505.     BMI.S    mt_PortaDskip
  506.     AND.W    #$F000,n_period(A6)
  507.     OR.W    #856,n_period(A6)
  508. mt_PortaDskip
  509.     MOVE.W    n_period(A6),D0
  510.     AND.W    #$0FFF,D0
  511.     MOVE.W    D0,6(A5)
  512.     RTS
  513.  
  514. mt_SetTonePorta
  515.     MOVE.L    A0,-(SP)
  516.     MOVE.W    (A6),D2
  517.     AND.W    #$0FFF,D2
  518.     MOVEQ    #0,D0
  519.     MOVE.B    n_finetune(A6),D0
  520.     MULU    #37*2,D0
  521.     LEA    mt_PeriodTable(PC),A0
  522.     ADD.L    D0,A0
  523.     MOVEQ    #0,D0
  524. mt_StpLoop
  525.     CMP.W    (A0,D0.W),D2
  526.     BHS.S    mt_StpFound
  527.     ADDQ.W    #2,D0
  528.     CMP.W    #37*2,D0
  529.     BLO.S    mt_StpLoop
  530.     MOVEQ    #35*2,D0
  531. mt_StpFound
  532.     MOVE.B    n_finetune(A6),D2
  533.     AND.B    #8,D2
  534.     BEQ.S    mt_StpGoss
  535.     TST.W    D0
  536.     BEQ.S    mt_StpGoss
  537.     SUBQ.W    #2,D0
  538. mt_StpGoss
  539.     MOVE.W    (A0,D0.W),D2
  540.     MOVE.L    (SP)+,A0
  541.     MOVE.W    D2,n_wantedperiod(A6)
  542.     MOVE.W    n_period(A6),D0
  543.     CLR.B    n_toneportdirec(A6)
  544.     CMP.W    D0,D2
  545.     BEQ.S    mt_ClearTonePorta
  546.     BGE    mt_Return2
  547.     MOVE.B    #1,n_toneportdirec(A6)
  548.     RTS
  549.  
  550. mt_ClearTonePorta
  551.     CLR.W    n_wantedperiod(A6)
  552.     RTS
  553.  
  554. mt_TonePortamento
  555.     MOVE.B    n_cmdlo(A6),D0
  556.     BEQ.S    mt_TonePortNoChange
  557.     MOVE.B    D0,n_toneportspeed(A6)
  558.     CLR.B    n_cmdlo(A6)
  559. mt_TonePortNoChange
  560.     TST.W    n_wantedperiod(A6)
  561.     BEQ    mt_Return2
  562.     MOVEQ    #0,D0
  563.     MOVE.B    n_toneportspeed(A6),D0
  564.     TST.B    n_toneportdirec(A6)
  565.     BNE.S    mt_TonePortaUp
  566. mt_TonePortaDown
  567.     ADD.W    D0,n_period(A6)
  568.     MOVE.W    n_wantedperiod(A6),D0
  569.     CMP.W    n_period(A6),D0
  570.     BGT.S    mt_TonePortaSetPer
  571.     MOVE.W    n_wantedperiod(A6),n_period(A6)
  572.     CLR.W    n_wantedperiod(A6)
  573.     BRA.S    mt_TonePortaSetPer
  574.  
  575. mt_TonePortaUp
  576.     SUB.W    D0,n_period(A6)
  577.     MOVE.W    n_wantedperiod(A6),D0
  578.     CMP.W    n_period(A6),D0
  579.     BLT.S    mt_TonePortaSetPer
  580.     MOVE.W    n_wantedperiod(A6),n_period(A6)
  581.     CLR.W    n_wantedperiod(A6)
  582.  
  583. mt_TonePortaSetPer
  584.     MOVE.W    n_period(A6),D2
  585.     MOVE.B    n_glissfunk(A6),D0
  586.     AND.B    #$0F,D0
  587.     BEQ.S    mt_GlissSkip
  588.     MOVEQ    #0,D0
  589.     MOVE.B    n_finetune(A6),D0
  590.     MULU    #36*2,D0
  591.     LEA    mt_PeriodTable(PC),A0
  592.     ADD.L    D0,A0
  593.     MOVEQ    #0,D0
  594. mt_GlissLoop
  595.     CMP.W    (A0,D0.W),D2
  596.     BHS.S    mt_GlissFound
  597.     ADDQ.W    #2,D0
  598.     CMP.W    #36*2,D0
  599.     BLO.S    mt_GlissLoop
  600.     MOVEQ    #35*2,D0
  601. mt_GlissFound
  602.     MOVE.W    (A0,D0.W),D2
  603. mt_GlissSkip
  604.     MOVE.W    D2,6(A5) ; Set period
  605.     RTS
  606.  
  607. mt_Vibrato
  608.     MOVE.B    n_cmdlo(A6),D0
  609.     BEQ.S    mt_Vibrato2
  610.     MOVE.B    n_vibratocmd(A6),D2
  611.     AND.B    #$0F,D0
  612.     BEQ.S    mt_vibskip
  613.     AND.B    #$F0,D2
  614.     OR.B    D0,D2
  615. mt_vibskip
  616.     MOVE.B    n_cmdlo(A6),D0
  617.     AND.B    #$F0,D0
  618.     BEQ.S    mt_vibskip2
  619.     AND.B    #$0F,D2
  620.     OR.B    D0,D2
  621. mt_vibskip2
  622.     MOVE.B    D2,n_vibratocmd(A6)
  623. mt_Vibrato2
  624.     MOVE.B    n_vibratopos(A6),D0
  625.     LEA    mt_VibratoTable(PC),A4
  626.     LSR.W    #2,D0
  627.     AND.W    #$001F,D0
  628.     MOVEQ    #0,D2
  629.     MOVE.B    n_wavecontrol(A6),D2
  630.     AND.B    #$03,D2
  631.     BEQ.S    mt_vib_sine
  632.     LSL.B    #3,D0
  633.     CMP.B    #1,D2
  634.     BEQ.S    mt_vib_rampdown
  635.     MOVE.B    #255,D2
  636.     BRA.S    mt_vib_set
  637. mt_vib_rampdown
  638.     TST.B    n_vibratopos(A6)
  639.     BPL.S    mt_vib_rampdown2
  640.     MOVE.B    #255,D2
  641.     SUB.B    D0,D2
  642.     BRA.S    mt_vib_set
  643. mt_vib_rampdown2
  644.     MOVE.B    D0,D2
  645.     BRA.S    mt_vib_set
  646. mt_vib_sine
  647.     MOVE.B    0(A4,D0.W),D2
  648. mt_vib_set
  649.     MOVE.B    n_vibratocmd(A6),D0
  650.     AND.W    #15,D0
  651.     MULU    D0,D2
  652.     LSR.W    #7,D2
  653.     MOVE.W    n_period(A6),D0
  654.     TST.B    n_vibratopos(A6)
  655.     BMI.S    mt_VibratoNeg
  656.     ADD.W    D2,D0
  657.     BRA.S    mt_Vibrato3
  658. mt_VibratoNeg
  659.     SUB.W    D2,D0
  660. mt_Vibrato3
  661.     MOVE.W    D0,6(A5)
  662.     MOVE.B    n_vibratocmd(A6),D0
  663.     LSR.W    #2,D0
  664.     AND.W    #$003C,D0
  665.     ADD.B    D0,n_vibratopos(A6)
  666.     RTS
  667.  
  668. mt_TonePlusVolSlide
  669.     BSR    mt_TonePortNoChange
  670.     BRA    mt_VolumeSlide
  671.  
  672. mt_VibratoPlusVolSlide
  673.     BSR.S    mt_Vibrato2
  674.     BRA    mt_VolumeSlide
  675.  
  676. mt_Tremolo
  677.     MOVE.B    n_cmdlo(A6),D0
  678.     BEQ.S    mt_Tremolo2
  679.     MOVE.B    n_tremolocmd(A6),D2
  680.     AND.B    #$0F,D0
  681.     BEQ.S    mt_treskip
  682.     AND.B    #$F0,D2
  683.     OR.B    D0,D2
  684. mt_treskip
  685.     MOVE.B    n_cmdlo(A6),D0
  686.     AND.B    #$F0,D0
  687.     BEQ.S    mt_treskip2
  688.     AND.B    #$0F,D2
  689.     OR.B    D0,D2
  690. mt_treskip2
  691.     MOVE.B    D2,n_tremolocmd(A6)
  692. mt_Tremolo2
  693.     MOVE.B    n_tremolopos(A6),D0
  694.     LEA    mt_VibratoTable(PC),A4
  695.     LSR.W    #2,D0
  696.     AND.W    #$001F,D0
  697.     MOVEQ    #0,D2
  698.     MOVE.B    n_wavecontrol(A6),D2
  699.     LSR.B    #4,D2
  700.     AND.B    #$03,D2
  701.     BEQ.S    mt_tre_sine
  702.     LSL.B    #3,D0
  703.     CMP.B    #1,D2
  704.     BEQ.S    mt_tre_rampdown
  705.     MOVE.B    #255,D2
  706.     BRA.S    mt_tre_set
  707. mt_tre_rampdown
  708.     TST.B    n_vibratopos(A6)
  709.     BPL.S    mt_tre_rampdown2
  710.     MOVE.B    #255,D2
  711.     SUB.B    D0,D2
  712.     BRA.S    mt_tre_set
  713. mt_tre_rampdown2
  714.     MOVE.B    D0,D2
  715.     BRA.S    mt_tre_set
  716. mt_tre_sine
  717.     MOVE.B    0(A4,D0.W),D2
  718. mt_tre_set
  719.     MOVE.B    n_tremolocmd(A6),D0
  720.     AND.W    #15,D0
  721.     MULU    D0,D2
  722.     LSR.W    #6,D2
  723.     MOVEQ    #0,D0
  724.     MOVE.B    n_volume(A6),D0
  725.     TST.B    n_tremolopos(A6)
  726.     BMI.S    mt_TremoloNeg
  727.     ADD.W    D2,D0
  728.     BRA.S    mt_Tremolo3
  729. mt_TremoloNeg
  730.     SUB.W    D2,D0
  731. mt_Tremolo3
  732.     BPL.S    mt_TremoloSkip
  733.     CLR.W    D0
  734. mt_TremoloSkip
  735.     CMP.W    #$40,D0
  736.     BLS.S    mt_TremoloOk
  737.     MOVE.W    #$40,D0
  738. mt_TremoloOk
  739.     MOVE.W    D0,8(A5)
  740.     MOVE.B    n_tremolocmd(A6),D0
  741.     LSR.W    #2,D0
  742.     AND.W    #$003C,D0
  743.     ADD.B    D0,n_tremolopos(A6)
  744.     RTS
  745.  
  746. mt_SampleOffset
  747.     MOVEQ    #0,D0
  748.     MOVE.B    n_cmdlo(A6),D0
  749.     BEQ.S    mt_sononew
  750.     MOVE.B    D0,n_sampleoffset(A6)
  751. mt_sononew
  752.     MOVE.B    n_sampleoffset(A6),D0
  753.     LSL.W    #7,D0
  754.     CMP.W    n_length(A6),D0
  755.     BGE.S    mt_sofskip
  756.     SUB.W    D0,n_length(A6)
  757.     LSL.W    #1,D0
  758.     ADD.L    D0,n_start(A6)
  759.     RTS
  760. mt_sofskip
  761.     MOVE.W    #$0001,n_length(A6)
  762.     RTS
  763.  
  764. mt_VolumeSlide
  765.     MOVEQ    #0,D0
  766.     MOVE.B    n_cmdlo(A6),D0
  767.     LSR.B    #4,D0
  768.     TST.B    D0
  769.     BEQ.S    mt_VolSlideDown
  770. mt_VolSlideUp
  771.     ADD.B    D0,n_volume(A6)
  772.     CMP.B    #$40,n_volume(A6)
  773.     BMI.S    mt_vsuskip
  774.     MOVE.B    #$40,n_volume(A6)
  775. mt_vsuskip
  776.     MOVE.B    n_volume(A6),D0
  777.     MOVE.W    D0,8(A5)
  778.     RTS
  779.  
  780. mt_VolSlideDown
  781.     MOVEQ    #0,D0
  782.     MOVE.B    n_cmdlo(A6),D0
  783.     AND.B    #$0F,D0
  784. mt_VolSlideDown2
  785.     SUB.B    D0,n_volume(A6)
  786.     BPL.S    mt_vsdskip
  787.     CLR.B    n_volume(A6)
  788. mt_vsdskip
  789.     MOVE.B    n_volume(A6),D0
  790.     MOVE.W    D0,8(A5)
  791.     RTS
  792.  
  793. mt_PositionJump
  794.     MOVE.B    n_cmdlo(A6),D0
  795.     SUBQ.B    #1,D0
  796.     MOVE.B    D0,mt_SongPos
  797. mt_pj2    CLR.B    mt_PBreakPos
  798.     ST     mt_PosJumpFlag
  799.     RTS
  800.  
  801. mt_VolumeChange
  802.     MOVEQ    #0,D0
  803.     MOVE.B    n_cmdlo(A6),D0
  804.     CMP.B    #$40,D0
  805.     BLS.S    mt_VolumeOk
  806.     MOVEQ    #$40,D0
  807. mt_VolumeOk
  808.     MOVE.B    D0,n_volume(A6)
  809.     MOVE.W    D0,8(A5)
  810.     RTS
  811.  
  812. mt_PatternBreak
  813.     MOVEQ    #0,D0
  814.     MOVE.B    n_cmdlo(A6),D0
  815.     MOVE.L    D0,D2
  816.     LSR.B    #4,D0
  817.     MULU    #10,D0
  818.     AND.B    #$0F,D2
  819.     ADD.B    D2,D0
  820.     CMP.B    #63,D0
  821.     BHI.S    mt_pj2
  822.     MOVE.B    D0,mt_PBreakPos
  823.     ST    mt_PosJumpFlag
  824.     RTS
  825.  
  826. mt_SetSpeed
  827.     MOVE.B    3(A6),D0
  828.     BEQ    mt_Return2
  829.     CLR.B    mt_counter
  830.     MOVE.B    D0,mt_speed
  831.     RTS
  832.  
  833. mt_CheckMoreEfx
  834.     BSR    mt_UpdateFunk
  835.     MOVE.B    2(A6),D0
  836.     AND.B    #$0F,D0
  837.     CMP.B    #$9,D0
  838.     BEQ    mt_SampleOffset
  839.     CMP.B    #$B,D0
  840.     BEQ    mt_PositionJump
  841.     CMP.B    #$D,D0
  842.     BEQ.S    mt_PatternBreak
  843.     CMP.B    #$E,D0
  844.     BEQ.S    mt_E_Commands
  845.     CMP.B    #$F,D0
  846.     BEQ.S    mt_SetSpeed
  847.     CMP.B    #$C,D0
  848.     BEQ    mt_VolumeChange
  849.     BRA    mt_PerNop
  850.  
  851. mt_E_Commands
  852.     MOVE.B    n_cmdlo(A6),D0
  853.     AND.B    #$F0,D0
  854.     LSR.B    #4,D0
  855.     BEQ.S    mt_FilterOnOff
  856.     CMP.B    #1,D0
  857.     BEQ    mt_FinePortaUp
  858.     CMP.B    #2,D0
  859.     BEQ    mt_FinePortaDown
  860.     CMP.B    #3,D0
  861.     BEQ.S    mt_SetGlissControl
  862.     CMP.B    #4,D0
  863.     BEQ    mt_SetVibratoControl
  864.     CMP.B    #5,D0
  865.     BEQ    mt_SetFineTune
  866.     CMP.B    #6,D0
  867.     BEQ    mt_JumpLoop
  868.     CMP.B    #7,D0
  869.     BEQ    mt_SetTremoloControl
  870.     CMP.B    #9,D0
  871.     BEQ    mt_RetrigNote
  872.     CMP.B    #$A,D0
  873.     BEQ    mt_VolumeFineUp
  874.     CMP.B    #$B,D0
  875.     BEQ    mt_VolumeFineDown
  876.     CMP.B    #$C,D0
  877.     BEQ    mt_NoteCut
  878.     CMP.B    #$D,D0
  879.     BEQ    mt_NoteDelay
  880.     CMP.B    #$E,D0
  881.     BEQ    mt_PatternDelay
  882.     CMP.B    #$F,D0
  883.     BEQ    mt_FunkIt
  884.     RTS
  885.  
  886. mt_FilterOnOff
  887.     MOVE.B    n_cmdlo(A6),D0
  888.     AND.B    #1,D0
  889.     ASL.B    #1,D0
  890.     AND.B    #$FD,$BFE001
  891.     OR.B    D0,$BFE001
  892.     RTS    
  893.  
  894. mt_SetGlissControl
  895.     MOVE.B    n_cmdlo(A6),D0
  896.     AND.B    #$0F,D0
  897.     AND.B    #$F0,n_glissfunk(A6)
  898.     OR.B    D0,n_glissfunk(A6)
  899.     RTS
  900.  
  901. mt_SetVibratoControl
  902.     MOVE.B    n_cmdlo(A6),D0
  903.     AND.B    #$0F,D0
  904.     AND.B    #$F0,n_wavecontrol(A6)
  905.     OR.B    D0,n_wavecontrol(A6)
  906.     RTS
  907.  
  908. mt_SetFineTune
  909.     MOVE.B    n_cmdlo(A6),D0
  910.     AND.B    #$0F,D0
  911.     MOVE.B    D0,n_finetune(A6)
  912.     RTS
  913.  
  914. mt_JumpLoop
  915.     TST.B    mt_counter
  916.     BNE    mt_Return2
  917.     MOVE.B    n_cmdlo(A6),D0
  918.     AND.B    #$0F,D0
  919.     BEQ.S    mt_SetLoop
  920.     TST.B    n_loopcount(A6)
  921.     BEQ.S    mt_jumpcnt
  922.     SUBQ.B    #1,n_loopcount(A6)
  923.     BEQ    mt_Return2
  924. mt_jmploop    MOVE.B    n_pattpos(A6),mt_PBreakPos
  925.     ST    mt_PBreakFlag
  926.     RTS
  927.  
  928. mt_jumpcnt
  929.     MOVE.B    D0,n_loopcount(A6)
  930.     BRA.S    mt_jmploop
  931.  
  932. mt_SetLoop
  933.     MOVE.W    mt_PatternPos(PC),D0
  934.     LSR.W    #4,D0
  935.     MOVE.B    D0,n_pattpos(A6)
  936.     RTS
  937.  
  938. mt_SetTremoloControl
  939.     MOVE.B    n_cmdlo(A6),D0
  940.     AND.B    #$0F,D0
  941.     LSL.B    #4,D0
  942.     AND.B    #$0F,n_wavecontrol(A6)
  943.     OR.B    D0,n_wavecontrol(A6)
  944.     RTS
  945.  
  946. mt_RetrigNote
  947.     MOVE.L    D1,-(SP)
  948.     MOVEQ    #0,D0
  949.     MOVE.B    n_cmdlo(A6),D0
  950.     AND.B    #$0F,D0
  951.     BEQ.S    mt_rtnend
  952.     MOVEQ    #0,D1
  953.     MOVE.B    mt_counter(PC),D1
  954.     BNE.S    mt_rtnskp
  955.     MOVE.W    (A6),D1
  956.     AND.W    #$0FFF,D1
  957.     BNE.S    mt_rtnend
  958.     MOVEQ    #0,D1
  959.     MOVE.B    mt_counter(PC),D1
  960. mt_rtnskp
  961.     DIVU    D0,D1
  962.     SWAP    D1
  963.     TST.W    D1
  964.     BNE.S    mt_rtnend
  965. mt_DoRetrig
  966.     MOVE.W    n_dmabit(A6),$DFF096    ; Channel DMA off
  967.     MOVE.L    n_start(A6),(A5)    ; Set sampledata pointer
  968.     MOVE.W    n_length(A6),4(A5)    ; Set length
  969.     MOVE.W    #300,D0
  970. mt_rtnloop1
  971.     DBRA    D0,mt_rtnloop1
  972.     MOVE.W    n_dmabit(A6),D0
  973.     BSET    #15,D0
  974.     MOVE.W    D0,$DFF096
  975.     MOVE.W    #300,D0
  976. mt_rtnloop2
  977.     DBRA    D0,mt_rtnloop2
  978.     MOVE.L    n_loopstart(A6),(A5)
  979.     MOVE.L    n_replen(A6),4(A5)
  980. mt_rtnend
  981.     MOVE.L    (SP)+,D1
  982.     RTS
  983.  
  984. mt_VolumeFineUp
  985.     TST.B    mt_counter
  986.     BNE    mt_Return2
  987.     MOVEQ    #0,D0
  988.     MOVE.B    n_cmdlo(A6),D0
  989.     AND.B    #$F,D0
  990.     BRA    mt_VolSlideUp
  991.  
  992. mt_VolumeFineDown
  993.     TST.B    mt_counter
  994.     BNE    mt_Return2
  995.     MOVEQ    #0,D0
  996.     MOVE.B    n_cmdlo(A6),D0
  997.     AND.B    #$0F,D0
  998.     BRA    mt_VolSlideDown2
  999.  
  1000. mt_NoteCut
  1001.     MOVEQ    #0,D0
  1002.     MOVE.B    n_cmdlo(A6),D0
  1003.     AND.B    #$0F,D0
  1004.     CMP.B    mt_counter(PC),D0
  1005.     BNE    mt_Return2
  1006.     CLR.B    n_volume(A6)
  1007.     MOVE.W    #0,8(A5)
  1008.     RTS
  1009.  
  1010. mt_NoteDelay
  1011.     MOVEQ    #0,D0
  1012.     MOVE.B    n_cmdlo(A6),D0
  1013.     AND.B    #$0F,D0
  1014.     CMP.B    mt_Counter,D0
  1015.     BNE    mt_Return2
  1016.     MOVE.W    (A6),D0
  1017.     BEQ    mt_Return2
  1018.     MOVE.L    D1,-(SP)
  1019.     BRA    mt_DoRetrig
  1020.  
  1021. mt_PatternDelay
  1022.     TST.B    mt_counter
  1023.     BNE    mt_Return2
  1024.     MOVEQ    #0,D0
  1025.     MOVE.B    n_cmdlo(A6),D0
  1026.     AND.B    #$0F,D0
  1027.     TST.B    mt_PattDelTime2
  1028.     BNE    mt_Return2
  1029.     ADDQ.B    #1,D0
  1030.     MOVE.B    D0,mt_PattDelTime
  1031.     RTS
  1032.  
  1033. mt_FunkIt
  1034.     TST.B    mt_counter
  1035.     BNE    mt_Return2
  1036.     MOVE.B    n_cmdlo(A6),D0
  1037.     AND.B    #$0F,D0
  1038.     LSL.B    #4,D0
  1039.     AND.B    #$0F,n_glissfunk(A6)
  1040.     OR.B    D0,n_glissfunk(A6)
  1041.     TST.B    D0
  1042.     BEQ    mt_Return2
  1043. mt_UpdateFunk
  1044.     MOVEM.L    A0/D1,-(SP)
  1045.     MOVEQ    #0,D0
  1046.     MOVE.B    n_glissfunk(A6),D0
  1047.     LSR.B    #4,D0
  1048.     BEQ.S    mt_funkend
  1049.     LEA    mt_FunkTable(PC),A0
  1050.     MOVE.B    (A0,D0.W),D0
  1051.     ADD.B    D0,n_funkoffset(A6)
  1052.     BTST    #7,n_funkoffset(A6)
  1053.     BEQ.S    mt_funkend
  1054.     CLR.B    n_funkoffset(A6)
  1055.  
  1056.     MOVE.L    n_loopstart(A6),D0
  1057.     MOVEQ    #0,D1
  1058.     MOVE.W    n_replen(A6),D1
  1059.     ADD.L    D1,D0
  1060.     ADD.L    D1,D0
  1061.     MOVE.L    n_wavestart(A6),A0
  1062.     ADDQ.L    #1,A0
  1063.     CMP.L    D0,A0
  1064.     BLO.S    mt_funkok
  1065.     MOVE.L    n_loopstart(A6),A0
  1066. mt_funkok
  1067.     MOVE.L    A0,n_wavestart(A6)
  1068.     MOVEQ    #-1,D0
  1069.     SUB.B    (A0),D0
  1070.     MOVE.B    D0,(A0)
  1071. mt_funkend
  1072.     MOVEM.L    (SP)+,A0/D1
  1073.     RTS
  1074.  
  1075.  
  1076. mt_FunkTable dc.b 0,5,6,7,8,10,11,13,16,19,22,26,32,43,64,128
  1077.  
  1078. mt_VibratoTable    
  1079.     dc.b   0, 24, 49, 74, 97,120,141,161
  1080.     dc.b 180,197,212,224,235,244,250,253
  1081.     dc.b 255,253,250,244,235,224,212,197
  1082.     dc.b 180,161,141,120, 97, 74, 49, 24
  1083.  
  1084. mt_PeriodTable
  1085. ; Tuning 0, Normal
  1086.     dc.w    856,808,762,720,678,640,604,570,538,508,480,453
  1087.     dc.w    428,404,381,360,339,320,302,285,269,254,240,226
  1088.     dc.w    214,202,190,180,170,160,151,143,135,127,120,113
  1089. ; Tuning 1
  1090.     dc.w    850,802,757,715,674,637,601,567,535,505,477,450
  1091.     dc.w    425,401,379,357,337,318,300,284,268,253,239,225
  1092.     dc.w    213,201,189,179,169,159,150,142,134,126,119,113
  1093. ; Tuning 2
  1094.     dc.w    844,796,752,709,670,632,597,563,532,502,474,447
  1095.     dc.w    422,398,376,355,335,316,298,282,266,251,237,224
  1096.     dc.w    211,199,188,177,167,158,149,141,133,125,118,112
  1097. ; Tuning 3
  1098.     dc.w    838,791,746,704,665,628,592,559,528,498,470,444
  1099.     dc.w    419,395,373,352,332,314,296,280,264,249,235,222
  1100.     dc.w    209,198,187,176,166,157,148,140,132,125,118,111
  1101. ; Tuning 4
  1102.     dc.w    832,785,741,699,660,623,588,555,524,495,467,441
  1103.     dc.w    416,392,370,350,330,312,294,278,262,247,233,220
  1104.     dc.w    208,196,185,175,165,156,147,139,131,124,117,110
  1105. ; Tuning 5
  1106.     dc.w    826,779,736,694,655,619,584,551,520,491,463,437
  1107.     dc.w    413,390,368,347,328,309,292,276,260,245,232,219
  1108.     dc.w    206,195,184,174,164,155,146,138,130,123,116,109
  1109. ; Tuning 6
  1110.     dc.w    820,774,730,689,651,614,580,547,516,487,460,434
  1111.     dc.w    410,387,365,345,325,307,290,274,258,244,230,217
  1112.     dc.w    205,193,183,172,163,154,145,137,129,122,115,109
  1113. ; Tuning 7
  1114.     dc.w    814,768,725,684,646,610,575,543,513,484,457,431
  1115.     dc.w    407,384,363,342,323,305,288,272,256,242,228,216
  1116.     dc.w    204,192,181,171,161,152,144,136,128,121,114,108
  1117. ; Tuning -8
  1118.     dc.w    907,856,808,762,720,678,640,604,570,538,508,480
  1119.     dc.w    453,428,404,381,360,339,320,302,285,269,254,240
  1120.     dc.w    226,214,202,190,180,170,160,151,143,135,127,120
  1121. ; Tuning -7
  1122.     dc.w    900,850,802,757,715,675,636,601,567,535,505,477
  1123.     dc.w    450,425,401,379,357,337,318,300,284,268,253,238
  1124.     dc.w    225,212,200,189,179,169,159,150,142,134,126,119
  1125. ; Tuning -6
  1126.     dc.w    894,844,796,752,709,670,632,597,563,532,502,474
  1127.     dc.w    447,422,398,376,355,335,316,298,282,266,251,237
  1128.     dc.w    223,211,199,188,177,167,158,149,141,133,125,118
  1129. ; Tuning -5
  1130.     dc.w    887,838,791,746,704,665,628,592,559,528,498,470
  1131.     dc.w    444,419,395,373,352,332,314,296,280,264,249,235
  1132.     dc.w    222,209,198,187,176,166,157,148,140,132,125,118
  1133. ; Tuning -4
  1134.     dc.w    881,832,785,741,699,660,623,588,555,524,494,467
  1135.     dc.w    441,416,392,370,350,330,312,294,278,262,247,233
  1136.     dc.w    220,208,196,185,175,165,156,147,139,131,123,117
  1137. ; Tuning -3
  1138.     dc.w    875,826,779,736,694,655,619,584,551,520,491,463
  1139.     dc.w    437,413,390,368,347,328,309,292,276,260,245,232
  1140.     dc.w    219,206,195,184,174,164,155,146,138,130,123,116
  1141. ; Tuning -2
  1142.     dc.w    868,820,774,730,689,651,614,580,547,516,487,460
  1143.     dc.w    434,410,387,365,345,325,307,290,274,258,244,230
  1144.     dc.w    217,205,193,183,172,163,154,145,137,129,122,115
  1145. ; Tuning -1
  1146.     dc.w    862,814,768,725,684,646,610,575,543,513,484,457
  1147.     dc.w    431,407,384,363,342,323,305,288,272,256,242,228
  1148.     dc.w    216,203,192,181,171,161,152,144,136,128,121,114
  1149.  
  1150. mt_chan1temp    dc.l    0,0,0,0,0,$00010000,0,  0,0,0,0
  1151. mt_chan2temp    dc.l    0,0,0,0,0,$00020000,0,  0,0,0,0
  1152. mt_chan3temp    dc.l    0,0,0,0,0,$00040000,0,  0,0,0,0
  1153. mt_chan4temp    dc.l    0,0,0,0,0,$00080000,0,  0,0,0,0
  1154.  
  1155. mt_SampleStarts    dc.l    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  1156.         dc.l    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  1157.  
  1158. mt_SongDataPtr    dc.l 0
  1159.  
  1160. mt_speed    dc.b 6
  1161. mt_counter    dc.b 0
  1162. mt_SongPos    dc.b 0
  1163. mt_PBreakPos    dc.b 0
  1164. mt_PosJumpFlag    dc.b 0
  1165. mt_PBreakFlag    dc.b 0
  1166. mt_LowMask    dc.b 0
  1167. mt_PattDelTime    dc.b 0
  1168. mt_PattDelTime2    dc.b 0,0
  1169.  
  1170. mt_PatternPos    dc.w 0
  1171. mt_DMACONtemp    dc.w 0
  1172.  
  1173. Equalizer1:    dc.w 0
  1174. Equalizer2:    dc.w 0
  1175. Equalizer3:    dc.w 0
  1176. Equalizer4:    dc.w 0
  1177. chan1:        dc.w 0
  1178. chan2:        dc.w 0
  1179. chan3:        dc.w 0
  1180. chan4:        dc.w 0
  1181. ;/* End of File */
  1182.